============= Main.as =============
package {
import flash.display.Sprite;
import flash.events.SampleDataEvent;
import flash.media.Sound;
import flash.utils.ByteArray;
import sora.graybox.GrayBox;

public class Main extends Sprite {
    
    private var _sound:Sound;  // ストリーミング再生を行うオブジェクト
    
    public const AUDIO_CHANNELS:int = 2;  // オーディオチャンネル数
    public const SAMPLE_RATE:Number = 44100.0;  // サンプリングレート
    public const BLOCK_SIZE:int = 4096;   // ブロックサイズ(バッファサイズ)
    public var audioBuffer:Vector.<Vector.<Number>>;  // オーディオバッファ
    public var grayBox:GrayBox;         // GrayBoxシステム基幹オブジェクト(モジュラーホスト)
    public var noiseGen:NoiseGenerator; // ノイズジェネレーター(モジュール)
    
    // 音声データ要求時実行のイベントハンドラー(AFLASH,AIR環境の場合)
    private function _sampleDataEvent(e:SampleDataEvent):void {
    // オーディオバッファのクリア -->
        var _outL:Vector.<Number> = audioBuffer[0],
            _outR:Vector.<Number> = audioBuffer[1];
        for (var i:int = 0; i < BLOCK_SIZE; i++) {
            _outL[i] = 0.0;
            _outR[i] = 0.0;
        }
    // GrayBoxによる音声処理 -->
        // GrayBox.process()メソッドを使用して音声処理を行います。
        // 第1引数 : 書き込みを行うオーディオバッファ
        // 第2引数 : 書き込み開始フレーム
        // 第3引数 : 書き込みフレーム数
        // ・今回はオーディオバッファ全体を使うので、開始フレームが0、書き込みフレーム数が4096
        // ・スロットナンバー0から順にモジュール側のIGrayBoxModule.process()メソッドが呼ばれます。
        grayBox.process(audioBuffer, 0, BLOCK_SIZE);
    // オーディオバッファからストリームへ書き込み -->
        var _stream:ByteArray = e.data;
        for (i = 0; i < BLOCK_SIZE; i++) {
            _stream.writeFloat(_outL[i]);
            _stream.writeFloat(_outR[i]);
        }
    }
    // コンストラクター
    public function Main():void {
    // エントリーポイント -->
    // ストリーミング再生を行うオブジェクト構築 -->
        _sound = new Sound();
    // オーディオバッファ作成 -->
        audioBuffer = new Vector.<Vector.<Number>>(2, true);
        audioBuffer[0] = new Vector.<Number>(BLOCK_SIZE, true); // チャンネル L
        audioBuffer[1] = new Vector.<Number>(BLOCK_SIZE, true); // チャンネル R
    // GrayBoxの構築 -->
        // 第1引数 : ブロックサイズ         ( 1~ ) FLASH,AIR環境は2048~8192フレーム
        // 第2引数 : サンプリングレート[Hz] ( 1~ ) FLASH,AIR環境は44100Hz固定
        // 第3引数 : オーディオチャンネル数 ( 2~ ) FLASH,AIR環境はLR2チャンネル固定
        // 第4引数 : モジュールスロット数   ( 1~ ) 今回はモジュールが1つなので１
        // ・初期値は必須パラメーターですが、構築時に確定できない場合は暫定値で構いません。
        //   その場合はストリーミングを開始する前に確定させてください。
        //   関連メソッド
        //   ブロックサイズ -> GrayBox.setProcessBlockSize()
        //   サンプリングレート -> GrayBox.setSampleRate()
        //   チャンネル数 -> GrayBox.setAudioChannels()
        //   スロット数 -> GrayBox.setModuleSlots()
        grayBox = new GrayBox(BLOCK_SIZE, SAMPLE_RATE, AUDIO_CHANNELS, 1);
    // 各GrayBoxモジュールの構築 -->
        // ノイズ音を出力し続けるモジュール
        noiseGen = new NoiseGenerator();
    // モジュールの接続 -->
        // GrayBox.attachModule()メソッドを使用し、ホストへモジュールを接続します。
        // 第1引数 : 接続するスロットのインデックス
        // 第2引数 : 接続するモジュールオブジェクト
        // 接続されたモジュールは接続スロットの先頭から順に処理が行われます。
        grayBox.attachModule(0, noiseGen);
    // ストリーミングの開始 -->
        _sound.addEventListener(SampleDataEvent.SAMPLE_DATA, _sampleDataEvent);
        _sound.play();
    }
}
}
======== NoiseGenerator.as ========
package {
    import sora.graybox.GrayBox;
    import sora.graybox.IGrayBoxModule;
    import sora.graybox.ProcessData;
// ノイズジェネレーターモジュール
public class NoiseGenerator implements IGrayBoxModule {
    public var volume:Number = 0.1;  // 音量
    // コンストラクター
    public function NoiseGenerator():void {}
// sora.graybox.IGrayBoxModule -->
    // ホストのサンプリングレートが変更された時に呼ばれるメソッド
    // GrayBox.setSampleRate() -> このメソッド
    public function updateSampleRate(sampleRate:Number):void{}
    // ホストのオーディオチャンネル数が変更された時に呼ばれるメソッド
    // GrayBox.setAudioChannels() -> このメソッド
    public function updateAudioChannels(ch:int):void{}
    // ホストのプロセスブロックサイズが変更された時に呼ばれるメソッド
    // GrayBox.setProcessBlockSize() -> このメソッド
    public function updateProcessBlockSize(size:int):void{}
    // ホストのGrayBox.resetModules()メソッドが使用された時に呼ばれるメソッド
    // GrayBox.resetModules() -> このメソッド
    public function resetModule():void{ volume = 0.1; }
    // ホストのGrayBox.initiModules()メソッドが使用された時に呼ばれるメソッド
    // GrayBox.initiModules() -> このメソッド
    public function initiModule():void{ volume = 0.1; }
    // このモジュールがホストへ接続された時に呼ばれるメソッド
    // GrayBox.attachModule() -> このメソッド
    public function connectModule(host:GrayBox):void{}
    // このモジュールがホストから取り外された時に呼ばれるメソッド
    // GrayBox.detachModule() -> このメソッド
    public function disconnectModule():void{}
    // このモジュールが接続されているスロットの、バイパス状況が更新された時に呼ばれるメソッド
    // GrayBox.bypassProcess() -> このメソッド
    public function updateBypassStatus(bypass:Boolean):void{}
    // ホストのGrayBox.startProcess()メソッドが使用された時に呼ばれるメソッド
    // GrayBox.startProcess() -> このメソッド
    public function startProcess():void{}
    // ホストのGrayBox.stopProcess()メソッドが使用された時に呼ばれるメソッド
    // GrayBox.stopProcess() -> このメソッド
    public function stopProcess():void{}
    // ホストのGrayBox.suspendProcess()メソッドが使用された時に呼ばれるメソッド
    // GrayBox.suspendProcess() -> このメソッド
    public function suspendProcess():void{}
    // ホストのGrayBox.resumeProcess()メソッドが使用された時に呼ばれるメソッド
    // GrayBox.resumeProcess() -> このメソッド
    public function resumeProcess():void{}
    
    // ホストが音声処理を実行した時に呼ばれるメソッド
    // GrayBox.process() -> このメソッド
    public function process(procData:ProcessData):void {
    // 音声処理準備 -->
        // ProcessDataオブジェクトはホストから音声処理に必要な情報を受け取り、
        // 各モジュールへ伝えるオブジェクトです。
        // ここではホストから渡されたオーディオバッファを参照して音声処理行います。
        var _outL:Vector.<Number> = procData.audioOut[0],  // 音声出力L
            _outR:Vector.<Number> = procData.audioOut[1],  // 音声出力R
            _startFrame:int = procData.offsetFrames,  // 音声処理開始フレーム
            _endFrame:int = _startFrame + procData.sampleFrames;  // 終了フレーム
    // 音声処理 -->
        for (var i:int = _startFrame; i < _endFrame; i++) {
            var _n:Number = Math.random() volume; // ノイズ音の生成
            // オーディオバッファに対して加算代入
            _outL[i] += _n; 
            _outR[i] += _n;
            // このモジュールしか音声処理を行わない場合は代入だけでも良い
            // _outL[i] = _n; 
            // _outR[i] = _n;
        }
    }
}
}
===================================